在本章中，我们将讨论PL/SQL中的集合。集合是具有相同数据类型的有序元素组。 每个元素都由一个唯一的下标来表示它在集合中的位置。

PL/SQL提供了三种集合类型 -

• 索引表或关联数组
• 嵌套的表
• 可变大小的数组或Varray类型

Oracle的每种类型的集合有以下特征 -

我们已经在“PL/SQL数组”一章中讨论了varray。 在本章中，将讨论PL/SQL表。

两种类型的PL/SQL表(即索引表和嵌套表)具有相同的结构，并且使用下标符号来访问它们的行。 但是，这两种表在一个方面有所不同， 嵌套表可以存储在数据库列中，索引表不能。

索引表

索引表(也称为关联数组)是一组键 - 值对。 每个键都是唯一的，用来定位相应的值。键可以是整数或字符串。使用以下语法创建索引表。 在这里，正在创建一个名为table_name的索引表，其中的键是subscript_type，关联的值是element_type，参考以下语法 -

TYPE type_name IS TABLE OF element_type [NOT NULL] INDEX BY subscript_type; 

table_name type_name;
SQL

示例

以下示例显示了如何创建一个表来存储整数值以及名称，然后打印出相同的名称列表。

SET SERVEROUTPUT ON SIZE 99999;
DECLARE 
   TYPE salary IS TABLE OF NUMBER INDEX BY VARCHAR2(20); 
   salary_list salary; 
   name   VARCHAR2(20); 
BEGIN 
   -- adding elements to the table 
   salary_list('Rajnish') := 62000; 
   salary_list('Minakshi') := 75000; 
   salary_list('Martin') := 100000; 
   salary_list('James') := 78000;  

   -- printing the table 
   name := salary_list.FIRST; 
   WHILE name IS NOT null LOOP 
      dbms_output.put_line 
      ('Salary of ' || name || ' is ' || TO_CHAR(salary_list(name))); 
      name := salary_list.NEXT(name); 
   END LOOP; 
END; 
/
SQL

执行上面示例代码，得到以下结果 -

Salary of James is 78000
Salary of Martin is 100000
Salary of Minakshi is 75000
Salary of Rajnish is 62000

PL/SQL 过程已成功完成。
Shell

示例2

索引表的元素也可以是任何数据库表的%ROWTYPE或任何数据库表字段的%TYPE。 以下示例说明了这个概念。我们将使用存储在数据库中的CUSTOMERS表及数据 -

CREATE TABLE CUSTOMERS( 
   ID   INT NOT NULL, 
   NAME VARCHAR (20) NOT NULL, 
   AGE INT NOT NULL, 
   ADDRESS CHAR (25), 
   SALARY   DECIMAL (18, 2),        
   PRIMARY KEY (ID) 
);
INSERT INTO CUSTOMERS (ID,NAME,AGE,ADDRESS,SALARY) 
VALUES (1, 'Ramesh', 32, 'Ahmedabad', 2000.00 );  

INSERT INTO CUSTOMERS (ID,NAME,AGE,ADDRESS,SALARY) 
VALUES (2, 'Khilan', 25, 'Delhi', 1500.00 );  

INSERT INTO CUSTOMERS (ID,NAME,AGE,ADDRESS,SALARY) 
VALUES (3, 'kaushik', 23, 'Kota', 2000.00 );

INSERT INTO CUSTOMERS (ID,NAME,AGE,ADDRESS,SALARY) 
VALUES (4, 'Chaitali', 25, 'Mumbai', 6500.00 ); 

INSERT INTO CUSTOMERS (ID,NAME,AGE,ADDRESS,SALARY) 
VALUES (5, 'Hardik', 27, 'Bhopal', 8500.00 );  

INSERT INTO CUSTOMERS (ID,NAME,AGE,ADDRESS,SALARY) 
VALUES (6, 'Komal', 22, 'MP', 4500.00 );
SQL

存储过程代码如下 -

SET SERVEROUTPUT ON SIZE 99999;
DECLARE 
   CURSOR c_customers is 
      select name from customers; 

   TYPE c_list IS TABLE of customers.name%type INDEX BY binary_integer; 
   name_list c_list; 
   counter integer :=0; 
BEGIN 
   FOR n IN c_customers LOOP 
      counter := counter +1; 
      name_list(counter) := n.name; 
      dbms_output.put_line('Customer('||counter||'):'||name_list(counter)); 
   END LOOP; 
END; 
/
SQL

执行上面示例代码，得到以下结果 -

嵌套表

嵌套表就像一个具有任意数量元素的一维数组。但是，嵌套表与数组在以下几个方面不同 -

• 数组是一个有声明数量的元素集合，但是一个嵌套的表没有。嵌套表的大小可以动态增加。
• 数组总是密集的，即它总是具有连续的下标。 嵌套数组最初是密集的，但是当从其中删除元素时，它可能变得稀疏。

使用以下语法创建嵌套表 -

TYPE type_name IS TABLE OF element_type [NOT NULL]; 

table_name type_name;
SQL

这个声明类似于索引表的声明，只是没有INDEX BY子句。

嵌套表可以存储在数据库列中。 它可以进一步用于简化SQL操作，您可以使用更大的表来连接单列表。关联数组不能存储在数据库中。

示例1下面的例子说明了嵌套表的使用 -

SET SERVEROUTPUT ON SIZE 99999;
DECLARE 
   TYPE names_table IS TABLE OF VARCHAR2(10); 
   TYPE grades IS TABLE OF INTEGER;  
   names names_table; 
   marks grades; 
   total integer; 
BEGIN 
   names := names_table('Kavita', 'Pritam', 'Ayan', 'Rishav', 'Aziz'); 
   marks:= grades(98, 97, 78, 87, 92); 
   total := names.count; 
   dbms_output.put_line('Total '|| total || ' Students'); 
   FOR i IN 1 .. total LOOP 
      dbms_output.put_line('Student:'||names(i)||', Marks:' || marks(i)); 
   end loop; 
END; 
/
SQL

当上面的代码在SQL提示符下执行时，它会产生以下结果 -

Total 5 Students
Student:Kavita, Marks:98
Student:Pritam, Marks:97
Student:Ayan, Marks:78
Student:Rishav, Marks:87
Student:Aziz, Marks:92

PL/SQL 过程已成功完成。
Shell

示例2

嵌套表的元素也可以是任何数据库表的%ROWTYPE或任何数据库表字段的%TYPE。以下示例说明了这个概念。我们将使用存储在数据库中的CUSTOMERS表，参考以下代码的实现 -

SET SERVEROUTPUT ON SIZE 99999;
DECLARE 
   CURSOR c_customers is  
      SELECT  name FROM customers;  
   TYPE c_list IS TABLE of customers.name%type; 
   name_list c_list := c_list(); 
   counter integer :=0; 
BEGIN 
   FOR n IN c_customers LOOP 
      counter := counter +1; 
      name_list.extend; 
      name_list(counter)  := n.name; 
      dbms_output.put_line('Customer('||counter||'):'||name_list(counter)); 
   END LOOP; 
END; 
/
SQL

执行上面示例代码，得到以下结果 -

集合方法

PL/SQL提供了内置的集合方法，使集合更易于使用。下表列出了方法及其用途 -

集合异常

下表提供了集合异常情况以及何时引发 -